CARA MENGHITUNG BUNGA BANK DENGAN EXEL

melakukan pinjaman di bank, kita akan disodori selembar kertas yang berisi tabel yang berisi jumlah pinjaman, masa pinjaman, dan besarnya angsuran yang harus di bayar tiap bulannya. Bahkan kadang kita tidak tahu sistem bunga apa yang diterapkan oleh bank tersebut, pakai bunga efektif ( effective rate ) atau bunga tetap ( flate rate ). Berapa yang harus kita bayar, jika kita menutup angsuran tersebut pada bulan ke – n ? Belum lagi jika kita melakukan perbandingan cicilan pada beberapa bank, misal lebih banyak mana cicilan yang harus kita bayar jika pada bank a menerapkan effektive rate 19 % / tahun dengan bank b yang menerapkan flate rate 12 % / tahun ?

Flate Rate
Pada flate rate, perhitungan cicilan relatif lebih mudah di banding dengan effective rate. Disini kita hanya melakukan perhitungan :
Cicilan = (pinjaman/jangka waktu dlm bulan) + ( pinjaman / bunga dlm bulan )

misal :
pinjaman (A1) = 10.000.000 (B1)
bunga (A2) = 12 %/ tahun (B2)
Angsuran (A3) = 3 tahun (B3), maka
Cicilan = (10.000.000/ 3 / 12% ) + ( 10.000.000 * 12% / 12 ) = 377.777,78
Excel cell (B4) =(B1/B3/12)+(B1*B2/12)

Effective Rate
Pada perhitungan effective rate, perhitungan bunga tidak di hitung secara global seperti pada flate rate. Disini yang di hitung adalah sisa pokok ( sisa angsuran kita ) yang di kalikan bunga. Dikarenakan angsuran yang kita bayar tiap bulannya tetap, maka pada tiap-tiap bulan perbandingan antara pengurangan hutang pokok dan bunga berbeda. Jumlah pokok kita tiap bulan naik, dan bunga semakin menurun. Tidak seperti di flate rate yang pokok dan bunga setiap bulannya selalu tetap.
Memang perhitungan ini sangatlah rumit, tapi di excel kita mempunyai fungsi finansial ( financial function ) yaitu programming excel untuk finance :

PMT (rate; nper; pv; fv; type)
Rate is the interest rate for the loan.
Nper is the total number of payments for the loan.
Pv is the present value, or the total amount that a series of future payments is worth now; also known as the principal.
Fv is the future value, or a cash balance you want to attain after the last payment is made. If fv is omitted, it is assumed to be 0 (zero), that is, the future value of a loan is 0.
Type is the number 0 (zero) or 1 and indicates when payments are due.

Set type equal to	If payments are due
0 or omitted	At the end of the period
1	At the beginning of the period

Remarks

• The payment returned by PMT includes principal and interest but no taxes, reserve payments, or fees sometimes associated with loans.
• Make sure that you are consistent about the units you use for specifying rate and nper. If you make monthly payments on a four-year loan at an annual interest rate of 12 percent, use 12%/12 for rate and 4*12 for nper. If you make annual payments on the same loan, use 12 percent for rate and 4 for nper.

misal :
pinjaman (A1) = 10.000.000 (B1)
bunga (A2) = 19 %/ tahun (B2)
Angsuran (A3) = 3 tahun (B3), maka
Excel cell (B4) =PMT(B2/12;B3*12;-B1)
=PMT(19%/12; 3*12; -10.000.000)
= 366.560,20

Jadi, jika pinjaman kita 10.000.000 di angsur selama 3 tahun, antara flate rate yg menggunakan bunga 12%/ tahun dengan effective rate 19% / tahun, masih sedikit effective rate kan ??? Untuk simulasi pinjaman, bunga dan jangka angsuran lainnya silahkan disimulasi sendiri ya…
Lalu bagai mana jika kita ingin mengetahui jumlah pokok yang sudah terbayar, sisa angsuran pada bulan ke-n ???
Mari kita buat saja tabel dari excel :
..

	A	B	C	D	E	F
1	Pinjaman	10.000.000		Angsuran	=B186
2	Bunga/th	19,00%		Pokok	=C186
3	J.Waktu	3	tahun	Bunga	=D186
4
5	Bln ke	Angsuran	Pokok	Bunga	Pokok s.d.	Sisa Pokok
6	1
7	2
185	180
186		=SUM(B6:B185)	=SUM(C6:C185)	=SUM(D6:D185)

B6 =IF(A6<= ($B$3*12);PMT($B$2/12;$B$3*12;-$B$1);”")
B7 =IF(A7<= ($B$3*12);PMT($B$2/12;$B$3*12;-$B$1);”")
B185 =IF(A185<= ($B$3*12);PMT($B$2/12;$B$3*12;-$B$1);”")
C6 =IF(A6<= ($B$3*12);PPMT($B$2/12;$A6;$B$3*12;-$B$1);”")
C7 =IF(A7<= ($B$3*12);PPMT($B$2/12;$A7;$B$3*12;-$B$1);”")
C185 =IF(A185<= ($B$3*12);PPMT($B$2/12;$A185;$B$3*12;-$B$1);”")
D6 =IF(A6<=($B$3*12);IPMT($B$2/12;$A6;$B$3*12;-$B$1);”")
D7 =IF(A7<=($B$3*12);IPMT($B$2/12;$A7;$B$3*12;-$B$1);”")
D185 =IF(A185<=($B$3*12);IPMT($B$2/12;$A185;$B$3*12;-$B$1);”")
E6 =C6
E7 =IF(A7<=($B$3*12);E6+C7;”")
E185 =IF(A185<=($B$3*12);E184+C185;”")
F6 =IF($A6<=($B$3*12);$B$1-$E6;”")
F7 =IF($A7<=($B$3*12);$B$1-$E7;”")
F185 =IF($A185<=($B$3*12);$B$1-$E185;”")

Keterangan :
Untuk cell B8 sampai F184 silahkan di copy paste. Tabel ini berlaku sampai dengan 180 bulan, untuk angsuran yang lebih dari 180 bulan, silahkan ditambahkan lagi….